{
  self,
  inputs,
  ...
}: let
  lib' = import ../shared/lib inputs.nixpkgs.lib;
  mkSystem = args:
    inputs.nixpkgs.lib.nixosSystem {
      specialArgs = {inherit inputs lib';};
      modules = (args.modules or []) ++ [../modules];
    };

  base = [
    ({
      config,
      specialArgs,
      ...
    }: {
      home-manager = {
        users.${config.local.systemVars.username}.imports = [
          ../modules/hm
          "${self}/config/home-manager"
        ];

        extraSpecialArgs = specialArgs;
      };
    })
  ];

  graphical = [
    ({config, ...}: {
      home-manager.users.${config.local.systemVars.username}.imports = [
        "${self}/config/home-manager/terminal/emulators/foot.nix"
      ];
    })
  ];
in {
  vamos = mkSystem {
    modules =
      [
        ./vamos
        inputs.nixos-hardware.nixosModules.framework-13-7040-amd
      ]
      ++ base
      ++ graphical;
  };

  solaire = mkSystem {
    modules =
      [
        ./solaire
      ]
      ++ base
      ++ graphical;
  };

  anastacia = mkSystem {
    modules = [
      ./anastacia
    ];
  };
}